爱华网函数：COUNT(X,N) 参数： X为数组，N为计算周期
说明：统计N周期中满足X条件的周期数,若N=0则从第一个有效值开始。
示例：COUNT(CLOSE>OPEN,20);表示统计20周期内收阳的周期数。看下面的指标(自己取名吧)，有几条语句用了COUNT函数：
V1:=(MA(CLOSE,80)-MA(CLOSE,13)/3);
神奇线:MA((CLOSE-V1)/V1,1),coloryellow,linethick2;
买点:IF(CROSS(神奇线,0) AND LOW/REF(HIGH,1)<1.012,0.5,0),STICK;
稳赚:IF(COUNT(神奇线>REF(神奇线,1),3)=3 ANDCOUNT(神奇线<0,10)=10 ANDREF(神奇线,3)=LLV(神奇线,10),0.5,0);
V2:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100;
V3:=(EMA(CLOSE, 6)-EMA(CLOSE, 12))*100;
猎庄:V3<13 ANDV2>9,stick,ColorFFFFFF,linethick2;
YD:=(count(c<ref(O,1),13)>=10 ORcount(c<ref(c,2),13)>=10) andcount(H/L>1.048,13)>=7;
DTJJ:=DMA(c,V/MA(V,13)/13);
XJPL:=c/DTJJ<0.91;
a1:=YD and XJPL;
STICKLINE(a1,0,0.50,4,1),colorffcccc;
回调买入:0,colorffcccc;
aa1:=cross(ref(c,3),ref(ma(c,20),3));
bb1:=count(c>ma(c,20),3)=3;
cc1:=cross(c,ma(c,20)) and(c-ma(c,20))/ma(c,20)>0.03;
突破月线:if((aa1 and bb1) orcc1,0.5,0),stick,linethick2,colorred;
drawicon((aa1 and bb1) or cc1,0.6,1);
指标解析:
V1:=(简单移动平均(收盘价,80)-简单移动平均(收盘价,13)/3);
神奇线:简单移动平均((收盘价-V1)/V1,1),coloryellow,linethick2;{画黄色粗线}
买点:条件函数(交叉函数(神奇线,0) AND最低价/向前引用(最高价,1)<1.012,0.5,0),棒状线;{在坐标0--0.5处画棒状线}
稳赚:条件函数(统计总数(神奇线>向前引用(神奇线,1),3)=3 AND统计总数(神奇线<0,10)=10 AND向前引用(神奇线,3)=最低值(神奇线,10),0.5,0);{在坐标0--0.5处显示脉冲信号}
V2:=(收盘价-向前引用(收盘价,1))/向前引用(收盘价,1)*100;
V3:=(指数平滑移动平均(收盘价, 6)-指数平滑移动平均(收盘价, 12))*100;
猎庄:V3<13 ANDV2>9,棒状线,ColorFFFFFF,linethick2;{默认在坐标0--1处画白色棒状线}
YD:=(统计总数(收盘价<向前引用(开盘价,1),13)>=10 OR统计总数(收盘价<向前引用(收盘价,2),13)>=10) and统计总数(最高价/最低价>1.048,13)>=7;
DTJJ:=动态移动平均(收盘价,成交量/简单移动平均(成交量,13)/13);
XJPL:=收盘价/DTJJ<0.91;
a1:=YD and XJPL;{两个条件同时成立}
画柱线(a1,0,0.50,4,1),colorffcccc;{在坐标0--0.5处画宽度为4的青色空心棒状线}
回调买入:0,colorffcccc;{在指标图上方显示'回调买入'}
aa1:=交叉函数(向前引用(收盘价,3),向前引用(简单移动平均(收盘价,20),3));
bb1:=统计总数(收盘价>简单移动平均(收盘价,20),3)=3;
cc1:=交叉函数(收盘价,简单移动平均(收盘价,20)) and(收盘价-简单移动平均(收盘价,20))/简单移动平均(收盘价,20)>0.03;
突破月线:条件函数((aa1 and bb1) orcc1,0.5,0),棒状线,linethick2,colorred;{在坐标0--0.5处画红色粗棒状线}
画图标((aa1 and bb1) or cc1,0.6,1);{在坐标0.6处显示红脸}
下面是几个运用COUNT函数的指标例句：
（1）、n日内阴线多于阳线
count(open>close,n)/n<0.5;
注：n为指标参数，可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值（如0.5等，达到确定阴线占全部K线个数的比例）。
（2）、n日内阳线多于阴线
count(open<close,n)/n>0.5;
注：n为指标参数，可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值（如0.5等，达到确定阳线占全部K线个数的比例）。
（3）、n日内上涨多于下跌（第二天开盘高于前一天收盘）
count(c>ref(c,1),n)/n>0.5;
注：n为指标参数，可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值（如0.5等，达到确定其中比例）。
（4）、n日内上涨少于下跌（第二天开盘低于前一天收盘）
count(c>ref(c,1),n)/n<0.5;
注：n为指标参数，可在参数设定范围内设定参数范围。同时可以自由编辑里面的数值（如0.5等，达到确定其中比例）。
（5）、连续n日收阳线
up:=close>open;
count(up,n)=n;
注：count(x,n),统计n周期中满足x条件的周期数，若n=0则从第一个有效值开始。n为指标参数，可在参数设定范围内设定参数范围。
（6）、连续n日内收阴线
up:=close<open;
count(up,n)=n;
注：count(x,n),统计n周期中满足x条件的周期数，若n=0则从第一个有效值开始。N为指标参数，可在参数设定范围内设定参数范围。
（7）、连续n天上涨
count(close>ref(close,1),n)=n;
注：count(x,n),统计n周期中满足x条件的周期数，若n=0则从第一个有效值开始。N为指标参数，可在参数设定范围内设定参数范围。
（8）、连续n天下跌
count(c<ref(c,1),n)=n;
注：count(x,n),统计n周期中满足x条件的周期数，若n=0则从第一个有效值开始。N为指标参数，可在参数设定范围内设定参数范围。
以上的参数n只要添入你所需要的周期数即可，如5、10、30等日期就是一个完整的指标或选股指标。
股市的不随机规律，隐藏在统计概率之中。用这两个函数，可以统计很多概率性的规律。
比如，以两天的收盘价相比，昨天是下跌的，今天的下跌的概率是多少？看下面指标：
{当日升跌概率}
A:=C<REF(C,1);
B:=REF(A,1) AND C>REF(C,1);{昨天下跌，今天上涨}
D:=REF(A,1) AND C=REF(C,1);{昨天下跌，今天平盘}
E:=REF(A,1) AND C<REF(C,1);{昨天下跌，今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盘概率:100*COUNT(D,0)/F;
那么连跌两天之后，第三天收盘的各种概率是多少？看下面指标：
A:=C<REF(C,1) andref(c,1)<ref(c,2);
B:=REF(A,1) AND C>REF(C,1);{前两天下跌,今天上涨}
D:=REF(A,1) AND C=REF(C,1);{前两天下跌,今天平盘}
E:=REF(A,1) AND C<REF(C,1);{前两天下跌,今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盘概率:100*COUNT(D,0)/F;
从指数的输出看，概率更明显了。
连跌三天之后呢？看下面指标：
A:=C<REF(C,1) and ref(c,1)<ref(c,2)and ref(c,2)<ref(c,3);
B:=REF(A,1) AND C>REF(C,1);{前三天下跌,今天上涨}
D:=REF(A,1) AND C=REF(C,1);{前三天下跌,今天平盘}
E:=REF(A,1) AND C<REF(C,1);{前三天下跌,今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盘概率:100*COUNT(D,0)/F;
规律就更明显了。
不要小看这些数据。虽然没有有些“高手”做出的成功率达百分之九十左右的公式那么夸张，但很有意义的。要知道股市中的随机因素太多，平衡性很强，稍稍的统计偏向，足可作为有用的参考。
大智慧引用函数FILTER、SUMBARS运用
1、函数:FILTER 信号过滤 过滤连续出现的信号。 用法：FILTER(X,N)，X满足条件后，删除其后N周期内的数据置为0。例如：FILTER(CLOSE>OPEN,5)，查找阳线，5天内再次出现的阳线不被记录在内。请看下面指标：
顶底背离:0,COLORYELLOW;
A1:=BARSLAST(ref(cross("macd.diff"(12,26,9),"macd.dea"(12,26,9)),1));
B1:=ref(c,A1+1)>c andref("macd.diff"(12,26,9),A1+1)<"macd.diff"(12,26,9)and cross("macd.diff"(12,26,9),"macd.dea"(12,26,9));
MACD底背离:STICKLINE(FILTER(B1>0,5),0,0.75,3,0),COLOR00FF00;{5天内B1>0的条件不被记录在内，在当前周期内出现B1>0画绿色柱线}
DRAWTEXT(FILTER(B1>0,5),0.57,'MACD底背离'),COLOR00FF00;
A2:=BARSLAST(ref(cross("kdj.k"(9,3,3),"kdj.d"(9,3,3)),1));
B2:=ref(c,A2+1)>c andref("kdj.k"(9,3,3),A2+1)<"kdj.k"(9,3,3) andcross("kdj.k"(9,3,3),"kdj.d"(9,3,3));
KDJ底背离:STICKLINE(FILTER(B2>0,5),0,1,3,0),COLORYELLOW;{5天内B2>0的条件不被记录在内，在当前周期内出现B>0画黄色柱线}
DRAWTEXT(FILTER(B2>0,5),0.80,'KDJ底背离'),COLORYELLOW;
A3:=BARSLAST(ref(cross("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24)),1));
B3:=ref(c,A3+1)>c andref("RSI.RSI1"(6,12,24),A3+1)<"RSI.RSI1"(6,12,24)and cross("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24));
RSI底背离:STICKLINE(FILTER(B3>0,5),0,0.5,3,0),COLORFFCC66;{5天内B3>0的条件不被记录在内，在当前周期内出现B3>0画青色柱线}
DRAWTEXT(FILTER(B3>0,5),0.25,'RSI底背离'),COLORFFCC66;
2,COLORRED;
C1:=BARSLAST(ref(cross("macd.dea"(12,26,9),"macd.diff"(12,26,9)),1));
D1:=ref(c,C1+1)<c andref("macd.diff"(12,26,9),C1+1)>"macd.diff"(12,26,9)and cross("macd.dea"(12,26,9),"macd.diff"(12,26,9));
MACD顶背离:STICKLINE(FILTER(D1>0,5),2,1.25,3,0),COLOR0066FF;{5天内D1>0的条件不被记录在内，在当前周期内出现D1>0画橘黄色柱线}
DRAWTEXT(FILTER(D1>0,5),1.47,'MACD顶背离'),COLOR0066FF;
C2:=BARSLAST(ref(cross("kdj.d"(9,3,3),"kdj.k"(9,3,3)),1));
D2:=ref(c,C2+1)<c andref("kdj.k"(9,3,3),C2+1)>"kdj.k"(9,3,3) andcross("kdj.d"(9,3,3),"kdj.k"(9,3,3));
KDJ顶背离:STICKLINE(FILTER(D2>0,5),2,1,3,0),COLORRED;{5天内D2>0的条件不被记录在内，在当前周期内出现D2>0画红色柱线}
DRAWTEXT(FILTER(D2>0,5),1.2,'KDJ顶背离'),COLORRED;
C3:=BARSLAST(ref(cross("RSI.RSI2"(6,12,24),"RSI.RSI1"(6,12,24)),1));
D3:=ref(c,C3+1)<c andref("RSI.RSI1"(6,12,24),C3+1)>"RSI.RSI1"(6,12,24)and cross("RSI.RSI2"(6,12,24),"RSI.RSI1"(6,12,24));
RSI顶背离:STICKLINE(FILTER(D3>0,5),2,1.5,3,0),COLORFF00FF;{5天内D3>0的条件不被记录在内，在当前周期内出现D3>0画粉色柱线}
DRAWTEXT(FILTER(D3>0,5),1.75,'RSI顶背离'),COLORFF00FF;
这是一个引用FILTER函数比较多的指标，请认真研究和体会一下语句的用法。
2、函数:SUMBARS 累加到指定周期数 向前累加到指定值到现在的周期数。用法：SUMBARS(X,A)，将X向前累加直到大于等于A，返回这个区间的周期数。例如：SUMBARS(VOL,CAPITAL)，求完全换手到现在的周期数。
这个函数好用，在于它不但能精确地得到统计结果，而且能得到“模糊”的结果。
就以SUMBARS(VOL,CAPITAL)为例：
日期数:SUMBARS(VOL,CAPITAL);{返回成交量累加到流通盘的日期数}
验证:SUM(V,日期数)/CAPITAL;{把返回的日期数之内的成交量累计，再除以流通盘}
运行的结果中，我们可以看到，“验证”的输出，除了SUMBARS起算点附近之外，从来没有小于1的。可见SUMBARS只往多算，不往少算。请看下面指标：
Var1:=(CLOSE-LLV(LOW,45))/(HHV(HIGH,45)-LLV(LOW,45))*100;
Var2:=SMA(Var1,3,1);
Var3:=SMA(Var2,3,1);
VarB:=SUM(IF(CLOSE>REF(CLOSE,7),VOL,IF(CLOSE<REF(CLOSE,7),0-VOL,0)),0);
VarC:=SUMBARS(VOL,CAPITAL);{求完全换手到现在的周期数}
VarD:=IF(CLOSE>LLV(CLOSE,VarC),1,-1);
VarE:=IF(VarB>LLV(VarB,VarC),1,-1);
VarF:=VarD*VarE;
Var10:=IF(VarF=-1,1,0);
关注:IF(Var10 AND CLOSE=LLV(CLOSE,20) ANDVar3<12,70,1),colorffcc66;{在图上0--70的坐标处显示青色脉冲信号}
V1:=SUM(IF(CLOSE>REF(CLOSE,1),VOL,IF(CLOSE<REF(CLOSE,1),0-VOL,0)),0);
V2:=SUMBARS(VOL,CAPITAL);{求完全换手到现在的周期数}
V3:=IF(CLOSE>LLV(CLOSE,V2),1,-1);
V4:=IF(V1>LLV(V1,V2),1,-1);
V5:=V3*V4;
V6:=IF(V5=-1,1,0);
V7:=COUNT(V6=1,8)>2;
V8:=AMOUNT/VOL/100;
V9:=(3*HIGH+LOW+OPEN+2*CLOSE)/7;
VA:=SUM(AMOUNT,13)/V8/100;
VB:=DMA(V9,VOL/VA);
VC:=(CLOSE-VB)/VB*100<-15;
VD:=(CLOSE-MIN(REF(CLOSE,5)*0.865,REF(CLOSE,21)*0.772))/CLOSE<0.05;
长针:(VC AND VD ANDV7)*60,coloryellow;{在图上0--60的坐标处显示黄色脉冲信号}
大智慧统计函数
（1）、AVEDEV 平均绝对偏差 用法：AVEDEV(X,N)含义：平均绝对偏差，求X的N日平均绝对偏差。请看指标：
TYP:=(HIGH+LOW+CLOSE)/(3);{最高+最底+收盘价/3}
趋势线:(TYP-MA(TYP,100))/((0.015)*(AVEDEV(TYP,100))),Color00FFFF;{(AVEDEV(TYP,100)求TYP的100日平均绝对偏差.}
（2）、DEVSQ 数据偏差平方和 用法：DEVSQ(X,N)含义：数据偏差平方和，求X的N日数据偏差平方和。数据偏差平方和除以N，即为方差。比较一下这2句在图上的区别：
a1：DEVSQ(C,5)/5;{0.025}
a2：DEVSQ(C,5);{0.126}
（3）、FORCAST 线性回归预测值 用法：FORCAST(X,N)为X的N周期线性回归预测值。示例：FORCAST(CLOSE,10) 表示求10周期线性回归预测。用最小二乘法求出N周期内X的一元线性回归线上的当天的值。请看指标：
平均价:=(HIGH+4*LOW+OPEN+CLOSE)/7;
均价差:= EMA(平均价,13) - EMA(平均价,34);
移动均价:= EMA(均价差,5);
差:=(均价差-移动均价)*5;
A:=IF(差>=1000 ,1000 ,IF(差<=平均价,平均价,差));
分水岭:=forcast(forcast(A,31),10),linethick3,COLORYELLOW;{求出31日内A的线性回归预测和10日线性回归预测}
上涨:if(A>分水岭,A,分水岭),LINETHICK2,colorred;
下跌:if(A<分水岭,A,分水岭),LINETHICK2,COLORGREEN;
分水岭1:forcast(forcast(A,31),10),linethick2,COLORYELLOW;{求出31日内A的线性回归预测和10日线性回归预测}
（4）、SLOPE 线性回归斜率用法：SLOPE(X,N)为X的N周期线性回归线的斜率。例如：SLOPE(CLOSE,10)表示求10周期线性回归线的斜率。请看指标：
XLB:forcast(V,8)/EMA(forcast(V,36),7);{forcast(V,8)求8周期线性回归预测}
XLL:if(slope(XLB,2)>0,slope(XLB,2)*XLB,0),linethick2;{slope(XLB,2)求2周期线性回归线的斜率}
drawicon(XLL<0.8,0,11);
drawicon(XLL>=0.8,0,10);
{排序，用于抓住量比放大，正在快速上涨的股。}
（5）、STD 估算标准差用法：STD(X,N)为X的N日估算标准差。例如：STD(CLOSE,10)，求10周期收盘价的估算标准差。请看指标：
var1:=ema((high+low+close)/3,3);
重心: var1,colorwhite;
varb:=amount/(100*vol);
varc:=ma(varb,34);
vard:=ma(close,26);
通道: (vard+varc)/2, coloryellow;
压力l: vard+2*std(close,49), colorred;{求49周期收盘价的估算标准差}
支持l: (vard-2*std(close,26)),colorgreen;{求26周期收盘价的估算标准差}
通道*1.062,colorff00ff;
通道*0.938,colorff00ff;
vare:=ma(winner(close),5)*100;
顶: drawtext(vare>60 andhigh>压力l,high,'卖'), color00ff00;
底: drawtext(vare<15 andcross(var1,通道),low,'买'),colorwhite;
（6）、STDP 总体标准差用法：STDP(X,N)为X的N日总体标准差。例如：STDP(CLOSE,10)，求10周期收盘价的总体标准差。请看指标：
VAR1:=AMOUNT/VOL/100;
VAR2:=(3*HIGH+LOW+OPEN+2*CLOSE)/7;
VAR3:=SUM(AMOUNT,34)/VAR1/100;
VAR4:=DMA(VAR2,VOL/VAR3);
VAR5:=100*(C-VAR4)/VAR4;
次强上轨:(MA(VAR5,20)+STDP(VAR5,20)),COLORRED;{STDP(VAR5,20)求20周期var5的总体标准差}
次强下轨:(MA(VAR5,20)-STDP(VAR5,20)),COLORRED;{STDP(VAR5,20)求20周期var5的总体标准差}
强弱线:(次强上轨+次强下轨)/2,POINTDOT,COLORYELLOW;
强势区上轨:(MA(VAR5,20)+1.7*STDP(VAR5,20)),COLOR10FFFF;{STDP(VAR5,20)求20周期var5的总体标准差}
强势区下轨:(MA(VAR5,20)-1.7*STDP(VAR5,20)),COLOR10FFFF;{STDP(VAR5,20)求20周期var5的总体标准差}
标准线:VAR5,COLORWHITE;
下面这2个函数用的比较少，略做简单介绍：
（7）、VAR 估算样本方差 用法：VAR(X,N)为X 的N日估算样本差。
（8）、VARP 总体样本方差 用法：VARP(X,N)为X的N日总体样本方差。
大智慧诊断指标的编写。
大智慧的诊断指标形同于飞狐、分析家的解盘指标，都是通过文字来提供当前盘面个股的趋势、均线、基本面、K线形态等技术指标的演化状态的，这对盘面分析很有帮助。
诊断指标是通过引用技术指标来完成文字诊断的。此外，还要用到文字诊断字符串输出函数，下面分别介绍所用到的函数：
1、IFS 字符串IF函数 用法：IFS(A>B,'返回A','返回B');
该函数返回一个字符串，上例表示：
如果A大于B，则返回'返回A'串，否则返回'返回B'串；
2、STR 数据到字符串转换函数用法:STR(X,N);
该函数返回一个字符串.上例子表示:范围精度为N的X的字符串;
诊断指标分两部分组成，前一部分是指标公式，后一部分是文字诊断。下面我们用实例来说明指标的编制:
{基本面 参数 n1:1 999 50 n2:1 999 10 p1:1 999 20 p2:1 999 50s1:1,99999,40000;s2:1,99999,10000}
m1:=FINANCE(33);{每股收益}
m2:=FINANCE(34);{每股净资产}
m3:=CAPITAL/1000000;{流通盘}
m4:=FINANCE(34);{净资产}
m5:=FINANCE(18);{公积金}
m6:=FINANCE(32);{未分配利润}
c1:=c/ref(ema(c,30),30);
c2:=indexc/ref(ema(indexc,30),30);
l1:=c1/c2*10-10;
c3:=c/ma(c,60);
c4:=indexc/ma(indexc,60);
l2:=c3/c4*10-10;
c5:=c/ma(c,120);
c6:=indexc/ma(indexc,120);
l3:=c5/c6*10-10;
L4:=MA(L1+L2+L3,5);
DIFF:="MACD.DIFF"(12,26,9);
DEA:="MACD.DEA"(12,26,9);
MACD:="MACD.MACD"(12,26,9);
K:="KD.K"(17,4,4);
D:="KD.D"(17,4,4);
{以上部分是公式，不能设有返回值，也就是全用":="赋值符。以下部分是引用上面的公式所做的文字诊断}
'【理想解盘】'+
'该股为'+
IFS(FINANCE(33)>=N1/100,'绩优、','')+IFS(FINANCE(33)<N1/100ANDFINANCE(33)>=N2/100,'中等业绩、','')+IFS(FINANCE(33)<N2/100ANDFINANCE(33)>=0,'绩差、','')+IFS(FINANCE(33)<0,'亏损、','')+
IFS(DYNAINFO(39)<=P1 ANDDYNAINFO(39)>0,'低市盈率、','')+IFS(DYNAINFO(39)>P1ANDDYNAINFO(39)<=P2,'中等市盈率、','')+IFS(DYNAINFO(39)>P2,'高市盈率、','')+IFS(FINANCE(7)>=S1,'大盘股。','')+IFS(FINANCE(7)<S1AND FINANCE(7)>=S2,'中盘股。','')+
IFS(FINANCE(7)<S2,'小盘股。','')+'流通盘(万)'+str(m3,4)+'。每股净资产为'+str(m4,2)+'，收益为'+str(m1,2)+'，市盈率为'+str(c/m1,3)+'，市净率为'+str(c/m2,2)+'，公积金为'+str(m5,2)+'，未分配利润为'+str(m6,2)+'。'+
{''之间的汉字作为字符串输出会显示在评价窗口中，str函数把数字转化为字符串输出。数据到字符串转换函数。
STR 用法:STR(X,N);该函数返回一个字符串.此例子表示:范围精度为N的X的字符串;}
{' '+}
IFS(REF(L4,1)>0 ANDREF(L4,1)>REF(L4,2),'该股中长期走势强于大盘，且近期继续走强。','')+
IFS(REF(L4,1)>0 ANDREF(L4,1)<=REF(L4,2),'该股中长期走势强于大盘，但近期有所走弱。','')+
IFS(REF(L4,1)<=0 ANDREF(L4,1)>REF(L4,2),'该股中长期走势弱于大盘，但近期有所转强。','')+
IFS(REF(L4,1)<=0 ANDREF(L4,1)<=REF(L4,2),'该股中长期走势弱于大盘，且近期继续走弱。','')+
IFS(DIFF>=0,'MACD指标显示该股处于多头行情中','MACD指标显示该股处于空头行情中')+
IFS(DIFF>=0 AND MACD>=0 ANDMACD>REF(MACD,1),'且有加速上涨趋势。','')+
IFS(DIFF>=0 AND MACD>=0 ANDMACD<=REF(MACD,1),'但上涨趋势有所减缓，短线投资者可逢高卖出，但当回落至均线或其他支撑位时应及时回补。','')+
IFS(DIFF>=0 AND MACD<0 ANDMACD>=REF(MACD,1),'，目前正处于回落整理阶段，但整理即将结束，可在均线或其他支撑位附近逢低买入，但当整理完成后选择再次向下突破时应注意及时止损。','')+
IFS(DIFF>=0 AND MACD<0 ANDMACD<REF(MACD,1),'，目前正处于回落整理阶段，且回落有加速趋势。','')+
IFS(DIFF<0 AND MACD<=0 ANDMACD<REF(MACD,1),'且有加速下跌趋势。','')+
IFS(DIFF<0 AND MACD<=0 ANDMACD>=REF(MACD,1),'但下跌趋势有所减缓，可在W&R指标大于90时逢低买入，但有可能再次加速下跌，注意及时止损。','')+
IFS(DIFF<0 AND MACD>0 ANDMACD>REF(MACD,1),'，目前正处于反弹阶段,投资者应保持谨慎。','')+
IFS(DIFF<0 AND MACD>0 ANDMACD<REF(MACD,1),'，短线反弹已经结束，应继续坚持谨慎原则。','')+
IFS(CROSS(DIFF,0),'该股今日从空头市场转换为多头行情。','')+
IFS(CROSS(0,DIFF),'该股今日从多头市场转换为空头行情。','')+
IFS(K>80 ANDCROSS(D,K)=0,'KD指标提示该股已经处于超买状态，如果KD指标死叉应及时卖出。','')+
IFS(K<20 ANDCROSS(K,D)=0,'KD指标提示该股已经处于超卖状态，如果KD指标金叉应及时买入。','')+
IFS(CROSS(K,D) ANDLLV(K,3)<20,'KD低位金叉，建议买入。','')+
IFS(CROSS(D,K) ANDHHV(K,3)>80,'KD高位死叉，建议卖出。','')
{每条语句以“+”符号结束，指标最后一句没有“+”的符号。}
注意：引用技术指标要准确无误以外，还要注意格式，否则不能通过测试。为了让朋友更明白一些，再举一例：
{KDJ解盘}
K:="KD.K"(17,4,4);
D:="KD.D"(17,4,4);
'【理想解盘】'+
IFS(K>80 ANDCROSS(D,K)=0,'KD指标提示该股已经处于超买状态，如果KD指标死叉应及时卖出。','')+
IFS(K<20 ANDCROSS(K,D)=0,'KD指标提示该股已经处于超卖状态，如果KD指标金叉应及时买入。','')+
IFS(CROSS(K,D) ANDLLV(K,3)<20,'KD低位金叉，建议买入。','')+
IFS(CROSS(D,K) ANDHHV(K,3)>80,'KD高位死叉，建议卖出。','')
朋友们可以照猫画虎自编一个，只要有一个成功了，你也就掌握了方法。
大智慧引用函数SUM的运用
函数：SUM(X,N) 参数： X为数组，N为计算周期
说明：统计N周期中X的总和,N=0则从第一个有效值开始。
示例：SUM(VOL,0) 表示统计从上市第一天以来的成交量总和。
SUM和COUNT这两个函数不同之处在于COUNT，计数。SUM，总数、和。请注意这两个函数的区别。
当数组为逻辑运算判断的结果时，SUM和COUNT的返回值是一样的。一般习惯上，对于逻辑运算信号,用COUNT统计，返回其它数值的，用SUM统计。当COUNT统计一般数值时，数组大于等于1时，计入；小于1时，不计入。这两个函数，主要用于统计。
用COUNT(CROSS(MA(C,5),MA(C,10)),0);就可以统计出全部的五天均线上穿十天均线的金叉数。
用SUM(CROSS(MA(C,5),MA(C,10)),0);和以上得出的结果应该是一样的。
请看下面的指标如何运用SUM函数的。
{多空曲 n:1 100 13 m:1 100 34}
obv:=sum(if(close>ref(close,1),vol,if(close<ref(close,1),0-vol,0)),0);
ah:=(sum(h,2)*(sum(1+winner(h),2))*sum(obv,2))/2;
al:=(sum(l,2)*(sum(1+winner(l),2))*sum(obv,2))/2;
a=(sum(o,2)*(sum(1+winner(o),2))*sum(obv,2))/2;
ac:=(sum(c,2)*(sum(1+winner(c),2))*sum(obv,2))/2;
stickline(ac>=ao,ah,al,0.1,0),colorred;{在ah与al之间画宽度为0.1的实心红柱线}
stickline(ac>=ao,ao,ac,4,0),colorred;{在ao与ac之间画宽度为4的实心红柱线}
stickline(ac<ao,ah,al,0.1,0),colorffcc66;{在ah与al之间画宽度为0.1的实心青柱线}
stickline(ac<ao,ao,ac,4,0),colorffcc66;{在ao与ac之间画宽度为4的实心青柱线}
两日参考:polyline(c>0,ma(ac,2)),colorff00ff;
ka1:=(hhv(ah,m)-llv(al,m))/m;
ka2:=sum(ac,n)/n;
m1:ka2-ka1*n,colorwhite;
m2:ka2+ka1*n,colorwhite;
多空分界:(m1+m2)/2,coloryellow;
指标解析：
{多空曲 n:1 100 13 m:1 100 34}
obv:=求和(条件函数(收盘价>向前引用(收盘价,1),成交量,条件函数(收盘价<向前引用(收盘价,1),0-成交量,0)),0);
ah:=(求和(最高价,2)*(求和(1+获利盘比例(最高价),2))*求和(obv,2))/2;
al:=(求和(最低价,2)*(求和(1+获利盘比例(最低价),2))*求和(obv,2))/2;
a=(求和(开盘价,2)*(求和(1+获利盘比例(开盘价),2))*求和(obv,2))/2;
ac:=(求和(收盘价,2)*(求和(1+获利盘比例(收盘价),2))*求和(obv,2))/2;
画柱线(ac>=ao,ah,al,0.1,0),colorred;
画柱线(ac>=ao,ao,ac,4,0),colorred;
画柱线(ac<ao,ah,al,0.1,0),colorffcc66;
画柱线(ac<ao,ao,ac,4,0),colorffcc66;
两日参考:画折线(收盘价>0,简单移动平均(ac,2)),colorff00ff;
ka1:=(最高值(ah,m)-最低值(al,m))/m;
ka2:=求和(ac,n)/n;
m1:ka2-ka1*n,colorwhite;
m2:ka2+ka1*n,colorwhite;
多空分界:(m1+m2)/2,coloryellow;
下面是几个运用sum函数的指标例句：
（1）、阶段缩量
sum(vol,n1)/capital<=n2;
注：n1为要统计的阶段时间，n2为缩量比例，可在参数设定范围内设定参数范围。
（2）、阶段放量
sum(vol,n1)/capital>=n2;
注：n1为要统计的阶段时间，n2为y放量比例，可在参数设定范围内设定参数范围。
（3）、放量上攻
a:=(c-ref(c,1))/ref(c,1)>=(n/100);
sum(vol,n1)/capital>=(n2/100) andcount(vol>ref(vol,1),n3 )=n3 andcount(a,n3)=n3;
完整含义：每日股价涨幅均大于n%，n1日内累计换手率大于n2%，并且成交量连续在n3日内放大。
（4）、阶段强势股
a:=sum(if(date-n=0,indexc,0),0);
b:=sum(if(date-n1=0,indexc,0)0);
e:=sum(if(date-n=0,c,0),0);
f:=sum(if(date-n1=0,c,0),0);
((f-e)/e)>((b-a)/a);
注：该公式求的是n日-n1日之间涨幅高于大盘的股票。n、n1参数的表达格式为yymmdd，注意在2000年前的表达为年份的后两位，例如1999年为99，从2000年开始以100依次向后累加，例如2001年9月14日为1010914，indexc函数表示同期大盘的收盘价，该函数对分笔成交分析周期无效。
（5）、阶段弱势股
a:=sum(if(date=n,indexc,0),0);
b:=sum(if(date=n1,indexc,0)0);
e:=sum(if(date=n,c,0),0);
f:=sum(if(date=n1,c,0),0);
((f-e)/e)<((b-a)/a);
注：该公式求的是n日-n1日之间涨幅低于大盘的股票。n、n1参数的表达格式为yymmdd，注意在2000年前的表达为年份的后两位，例如1999年为99，从2000年开始以100依次向后累加，例如2001年9月14日为1010914，indexc函数表示同期大盘的收盘价，该函数对分笔成交分析周期无效。
